2. Wikisource-Arbeitstreffen 2023/Wikidata

SPARQL-Abfragen

Boetticher

von Boetticher (1826-1902)

Frühlingslandschaft im Rosenthal

#title: Boetticher-KünstlerInnen im Stadtwiki Dresden
SELECT ?item ?itemLabel ?wikisource ?wikisourceLabel ?sitelink_URL (uri(concat('https://www.stadtwikidd.de/wiki/',?stadtwikiDD)) as ?Stadtwiki_URL)
WHERE 
{
  ?item wdt:P1343 wd:Q72628185.           # described by source im Boetticher
  ?item p:P1343 [ pq:P805 ?wikisource ].  # hole "Wikisource"-Item aus qualifier
  ?item wdt:P8713 ?stadtwikiDD.           # muss einen Artikel im Stadtwiki Dresden haben
  ?sitelink_URL schema:about ?wikisource. # hole SiteLink aus Wikisource-Item
  #FILTER  (STRSTARTS(str(?sitelink_URL), "https://de.wikisource.org/wiki/Boetticher")) . # filtere ggf. nach nur Boetticher-Artikeln
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". } # verwende deutschsprachige Labels
} ORDER BY ?itemLabel

Try it!

#title: Werke mit SKD ID von Künstler:innen, die im Boetticher aufgeführt sind
SELECT ?maler ?malerLabel ?werk ?werkLabel ?image
WHERE 
{
  ?werk wdt:P8917 ?skdid.
  ?werk wdt:P170 ?maler.
  optional{
    ?werk wdt:P18 ?image.
  }
  ?maler wdt:P1343 wd:Q72628185.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
} ORDER BY ?malerLabel

Try it!

Bocknetz

#defaultView:Graph
#title: Zitationsnetz zu Artikel von Carl Ernst Bock
SELECT ?Die_Gartenlaube ?Die_GartenlaubeLabel ?zitiert ?zitiertLabel ?edgeLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?Die_Gartenlaube wdt:P1433 wd:Q655617;
    wdt:P50 wd:Q75044.
  OPTIONAL { ?Die_Gartenlaube wdt:P2860 ?zitiert. }
  BIND("zitiert" AS ?edgeLabel)
}

Try it!

Gartenlaube

Die neue Elbebrücke zwischen Loschwitz und Blasewitz, 1893

#------------------------------------------------------------------------------------
#title: Abfrage der Wikisource-Artikel der Gartenlaube rund 10km um Dresden (#Nearby)
#------------------------------------------------------------------------------------
#defaultView:Map
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
SELECT ?item ?itemLabel ?subjectLabel ?coord ?layer
WHERE 
{
  ?item wdt:P1433 wd:Q655617. # alle Artikel in der Gartenlaube
  ?item wdt:P921 ?subject.    # mit main subject
  ?subject wdt:P7046 ?hovcode.# dieses sollte in Sachsen liegen
  wd:Q1731 wdt:P625 ?Dresden. # grenze nochmals auf Radius um Dresden 10km ein
		  SERVICE wikibase:around {
		    ?subject wdt:P625 ?coord.
		    bd:serviceParam wikibase:center ?Dresden.
		    bd:serviceParam wikibase:radius "10".
		    bd:serviceParam wikibase:distance ?dist.
		  }
  
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Jagden in der Steppe (1877)

#title: Reiseberichte von Alfred Brehm als Timeline
#defaultView:Timeline
SELECT DISTINCT ?article ?articleLabel ?pubDate (SAMPLE(?image) AS ?image)
WHERE
{
  ?article wdt:P1433 wd:Q655617.
  ?article wdt:P50 wd:Q155112.
  ?article wdt:P921 wd:Q1164267.
  ?article wdt:P577 ?pubDate.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
  optional {
    ?article wdt:P18 ?image. 
  }
} GROUP BY ?article ?articleLabel ?pubDate

Try it!

#title: Top 100 der zentralen Themen in der Gartenlaube
#defaultView:BubbleChart
SELECT ?subject ?subjectLabel (count(*) as ?count)
WHERE 
{
  ?item wdt:P1433 wd:Q655617.
  ?item wdt:P921 ?subject.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
} GROUP BY ?subject ?subjectLabel ORDER BY DESC(?count) LIMIT 100

Try it!

Hantzsch

#title: Hantzschstraßen in Wikisource als Wikidata-Karte
#defaultView:Map{"hide":"?coord"}
SELECT DISTINCT ?item ?itemLabel  ?itemDescription ?sitelink ?coord WHERE {

 ?item wdt:P8710 ?street.
 ?item wdt:P625 ?coord.
 ?item p:P1343 [ pq:P805 ?wikisource ].
 ?sitelink schema:about ?wikisource.
 FILTER  (STRSTARTS(str(?sitelink), "https://de.wikisource.org/")) .
 SERVICE wikibase:label {
      bd:serviceParam wikibase:language "de" .
      ?item rdfs:label ?itemLabel .
      ?item schema:description ?itemDescription .
    }
}

Try it!

Rittergüter

#defaultView:Map{"hide": ["?coords", "?topic"], "layer": "?albumLabel"}
SELECT (CONCAT(?albumLabel, " - ",?itemLabel) AS ?heading) ?album ?albumLabel ?item ?itemLabel ?topic ?topicLabel ?coords ?image {
  ?album wdt:P179 wd:Q19125856 .
  ?item wdt:P1433 ?album .
  ?item wdt:P921 ?topic .
  ?topic wdt:P625 ?coords .
  OPTIONAL { ?item wdt:P18 ?image } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,[AUTO_LANGUAGE],en". }
}
ORDER BY ?albumLabel ?topicLabel

Try it!

RE: Paulys Realencyclopädie

#title: Dresdner Autoren von RE-Einträgen
SELECT ?author ?authorLabel (count(*) as ?count)
WHERE 
{
  ?item wdt:P361 wd:Q1138524.       # aktuell 61415 Einträge zur RE (part of)
  ?item wdt:P50 ?author.            # hole Autor(en) des RE-Eintrages
  ?author wdt:P19 wd:Q1731. # Geburts- oder Sterbeort ist Dresden (Q1731) Pipe wdt:P20
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
} GROUP BY ?author ?authorLabel

Try it!

Federated (WS+Commons)

#defaultView:Map{"hide":"?coord"}
SELECT ?title ?coord ?image1 ?image2
WITH
{ SELECT ?file ?title ?pageid
  WHERE
  { SERVICE wikibase:mwapi
    {
      bd:serviceParam wikibase:api "Generator" .
      bd:serviceParam wikibase:endpoint "commons.wikimedia.org" .
      bd:serviceParam mwapi:gcmtitle "Category:Images_from_Wiki_Loves_Monuments_2023,_DE-SN" .
      bd:serviceParam mwapi:generator "categorymembers" .
      bd:serviceParam mwapi:gcmtype "file" .
      bd:serviceParam mwapi:gcmlimit "max" .
      ?title wikibase:apiOutput mwapi:title .
      ?pageid wikibase:apiOutput "@pageid" .
    }
    BIND (URI(CONCAT('https://commons.wikimedia.org/entity/M', ?pageid)) AS ?file)
  }
} AS %get_files
WHERE
{  INCLUDE %get_files
  ?file wdt:P180 ?depicts .
  ?file schema:url ?image2.
  service <https://query.wikidata.org/sparql> {
      ?album wdt:P179 wd:Q19125856 .
      ?item wdt:P1433 ?album .
      ?item wdt:P921 ?depicts.
      ?depicts wdt:P1708 ?denkmalid.
      ?depicts wdt:P625 ?coord.
      ?item wdt:P18 ?image1.  
    }
}

Try it!