Zum Inhalt springen

Projekt:Datenlaube-Kalender 2023

Aus Wikiversity

Projekt
Projekttitel	Datenlaube-Kalender für das Jahr 2023
Ansprechpartner	DieDatenlaube: Jens Bemme, Christian Erlinger, Matthias Erfurth
Laufzeit	2023, ab 2024: Immerwährender Datenlaube-Kalender
Kurzbeschreibung
Query-Sammlung anlässlich des Sammelbandes Citizen Science in den Geschichtswissenschaften, eine Hommage an die Gartenlaube-Kalender. Beitrag von uns: Die Datenlaube – Citizen Science & digitale historische Hilfswissenschaft, DOI: 10.14220/9783737015714.163

Die Datenlaube ist das Citizen Science-Projekt für offene Kulturdaten der Gartenlaube. Seit 2008 transkribiert und ocr-korrigiert eine wachsende Gemeinschaft in Wikisource diese Illustrierte aus Leipzig, d.h. insgesamt circa 18.500 Artikel des ersten deutschen Massenblatts seit 1853, vorerst bis 1899. Die Seite s:Wikisource:Wikidata#Die_Gartenlaube bietet diverse Queries für den Datenbestand. Wir ergänzen hier eine neue Sammlung zum Nutzen, zum Ergänzen und Variieren.

2024: Zu den Urnen!

#------------------------------------------------------------------------------------
#title:Die Gartenlaube zu den Grundfesten unseres politischen Systems
#------------------------------------------------------------------------------------
SELECT DISTINCT ?item ?itemLabel ?mainSubject ?mainSubjectLabel WHERE {
  ?item wdt:P1433 wd:Q655617;
    wdt:P921 ?mainSubject.
  VALUES ?democrazy {
    wd:Q166747
    wd:Q587404
    wd:Q7174
    wd:Q40231
    wd:Q35749
  }
  ?mainSubject (wd:P31|(wdt:P279*)|(wdt:P1269*)) ?democrazy.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Artikel bearbeitet in 2023

#------------------------------------------------------------------------------------
#title:Die Datenlaube: Edits in 2023
#------------------------------------------------------------------------------------
SELECT ?artikel ?artikelLabel ?dateModified WHERE {

  ?artikel wdt:P1433 wd:Q655617; schema:dateModified ?dateModified.
  FILTER(YEAR(?dateModified)=2023)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?dateModified)

Anmerkung: Die hier (und auch bereits 2022) verwendete SPARQL-Abfrage verwendet schema:dateModified als datumsbezogenen Wert. Das bedeutet, ein Item, dass 2022 und 2023 bearbeitet wurde, schlägt nur mehr in der 2023er-Query auf. Womöglich gibt es bessere Queries (MWAPI:SERVICE?) um die Bearbeitungsgeschichte im SPARQL-Endpoint miteinzubeziehen. Aber näherungsweise und v.a. aktuell zum Jahreswechsel gibt es einen guten Überblick über die Arbeit der Datenlaube im vergangen Jahr.

Klassen der als Schlagworte vergebenen Begriffe für Gartenlaube-Artikel

https://w.wiki/459 (links Bubble Chart klicken)

#------------------------------------------------------------------------------------
#title:Klassen der als Schlagworte vergebenen Begriffe für Artikel (Links im Menü Bubble Chart klicken!)
#------------------------------------------------------------------------------------
SELECT DISTINCT ?OberklasseLabel (COUNT(?Die_Gartenlaube) AS ?Anzahl) WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?Die_Gartenlaube wdt:P1433 wd:Q655617.
  ?Die_Gartenlaube wdt:P921 ?Schlagwort.
  ?Schlagwort wdt:P31 ?Oberklasse.
  
}
GROUP BY ?OberklasseLabel
ORDER BY DESC(?Anzahl)

Schlagwort (P921) <> beschrieben in (P1343)

#------------------------------------------------------------------------------------
#title:Gartenlaube-Artikel deren Schlagwort (P921) selbst durch den beschlagworteten Artikel beschrieben (P1343) wurde.
#------------------------------------------------------------------------------------
SELECT ?article ?articleLabel ?topic ?topicLabel WHERE {
  ?topic wdt:P1343 ?article.
  ?article wdt:P921 ?topic;
    wdt:P1433 wd:Q655617.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Untertitel, 1853-1899

#------------------------------------------------------------------------------------
#title: Subtitles of articles published in German 19th Century magazine Die Gartenlaube
#------------------------------------------------------------------------------------
SELECT ?laubenArtikel ?laubenArtikelLabel ?Untertitel WHERE {

  ?laubenArtikel wdt:P1433 wd:Q655617; wdt:P1680 ?Untertitel.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

}

Keil und Bock, Leipzig 1873

d:Q105687075#P2860

#------------------------------------------------------------------------------------
#titel: cited works in "Keil and Bock" issues I. and II. (Q105687075) as graph, coloured Items which are part of series
#------------------------------------------------------------------------------------
SELECT ?source ?sourceLabel ?item ?itemLabel ?rgb
#defaultView:Graph
WHERE 
{
  VALUES ?source {wd:Q105687075}
  ?source wdt:P2860 ?item.
  optional {
  ?item wdt:P179 ?series.
  }
  BIND(
     IF(?series = wd:Q98770474, "00ff00",
     IF(?series = wd:Q89043655, "ff00ff",
     IF(?series = wd:Q83165174, "ffff00",
       "ffffff"))) AS ?rgb).
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Wartungsliste: Artikel mit Illustration(en) ohne zentrales Thema

#------------------------------------------------------------------------------------
#title: Gartenlaubenartikel mit Illustration ohne main subject
#------------------------------------------------------------------------------------
#defaultView:ImageGrid
SELECT ?item ?itemLabel ?image WHERE {
    ?item wdt:P1433 wd:Q655617. # Artikel ist in der Gartenlaube erschienen
    ?item wdt:P18 ?image.       # ... und hat eine Illustration
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
    FILTER NOT EXISTS { ?item wdt:P921 ?mainSubject } # zeige alle Artikel ohne Main Subject an
}

subclass of Großkatze

#------------------------------------------------------------------------------------
#title:Großkatzen in der Gartenlaube
#------------------------------------------------------------------------------------
#defaultView:ImageGrid
SELECT DISTINCT ?item ?itemLabel ?image
WHERE 
{
  ?item wdt:P1433 wd:Q655617.    # Item ist in der Gartenlaube publiziert
  ?item wdt:P921 ?subject.       # Ein zentrales Thema beschäftigt sich mit ...
  ?subject wdt:P279 wd:Q6667323. # GROßKatzen als (subclass of Property:P279)
  optional {
   ?item wdt:P18 ?image.
  }
    bind (if(bound(?image), 
           ?image, 
           <http://commons.wikimedia.org/wiki/Special:FilePath/File:Die_Datenlaube.jpg>) as ?image)  # inkl. Platzhaltergrafik, wenn es kein Image gibt
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Heimatkalendr für Sachsen

#------------------------------------------------------------------------------------
#title: Abfrage von Illustrationen von Denkmälern in Sachsen aus 'Die Gartenlaube' bis 1899
#------------------------------------------------------------------------------------
#defaultView:ImageGrid
SELECT ?item ?itemLabel ?image
WHERE 
{
  ?item wdt:P1433 wd:Q655617. # wurde in Die Gartenlaube publiziert
  ?item wdt:P18 ?image.       # und eine Illustration
  ?item wdt:P921 wd:Q153015.  # befindet sich lt. Main Subject im Königreich Sachsen
  ?item wdt:P921 ?subject.    # und ein mainsubject ...
  ?subject wdt:P1708 ?lfds.   # ... ist beim Landesamt für Denkmalpflege gelistet
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

FactGrid:Die Gartenlaube

https://w.wiki/3Anq ist eine unvollständige Query der noch nicht systematisch in FactGrid erschlossenen Rezepte in der Gartenlaube, insb. aus dem Jahr 1898, vgl. Olaf Simons: Keine Selbstverständlichkeit: Citizen Science auf der FactGrid Wikibase-Plattform, DOI 10.14220/9783737015714.241, in: Citizen Science in den Geschichtswissenschaften : Methodische Perspektive oder perspektivlose Methode?, 2023, DOI 10.14220/9783737015714

Neuer Query Builder

Mit dem neuen Query Builder kannst du Abfragen erstellen, ohne Abfragen in SPARQL schreiben zu müssen.

Boetticher

Wikisource: Malerwerke des neunzehnten Jahrhunderts – Quellen und Volltexte

Transkription, Wikidata-Erschließung und Queries von Andreas Wagner

Die Datenlaube: Erschließung der Referenzen im Boetticher (Illustrierte und Kunstführer) und der Gartenlaube-Illustrationen in Wikisource und Wikidata, Queryideen willkommen!

Boettichers Maler:innen: Wikidata vs. FactGrid

#------------------------------------------------------------------------------------
#title: Wikidata-Items aus dem Boetticher mit Verlinkung auf FactGrid
#------------------------------------------------------------------------------------
SELECT ?item ?itemLabel (URI(CONCAT("https://database.factgrid.de/wiki/Item:",STR(?factgrID))) as ?FactGridUri)
WHERE 
{
  ?item wdt:P1343 wd:Q72628185.
  ?item wdt:P8168 ?factgrID
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Boetticher vs. SKD ID (P8917)

#------------------------------------------------------------------------------------
#title: Werke mit SKD ID von Künstler:innen, die im 'Boetticher' aufgeführt sind
#------------------------------------------------------------------------------------
SELECT ?maler ?malerLabel ?werk ?werkLabel ?image
WHERE 
{
  ?werk wdt:P8917 ?skdid.
  ?werk wdt:P170 ?maler.
  optional{
    ?werk wdt:P18 ?image.
  }
  ?maler wdt:P1343 wd:Q72628185.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
} ORDER BY ?malerLabel

Berlin

#------------------------------------------------------------------------------------
#title: Berlin
#------------------------------------------------------------------------------------
SELECT ?Artikel ?ArtikelLabel ?objLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?Artikel wdt:P31 wd:Q191067.
  ?Artikel wdt:P1433 wd:Q655617.
  ?Artikel wdt:P921 ?obj .
  ?obj wdt:P131* wd:Q64 .
}

via Alexander Winkler, https://openbiblio.social/@awinkler/110604867485662180

Schlagworte der Gartenlaube = Wikipedia-Artikel

#------------------------------------------------------------------------------------
#title: Wikipedia-Artikel(de), verknüpft mit Schlagworten (''main subject'' P921) von Gartenlaube-Artikeln
#------------------------------------------------------------------------------------
SELECT DISTINCT ?wpPage ?schlagwort WHERE {
  ?artikel wdt:P1433 wd:Q655617;
    wdt:P921 ?schlagwort.
  ?wpPage schema:about ?schlagwort;
    schema:isPartOf <https://de.wikipedia.org/>.
  #FILTER(CONTAINS(STR(?wiki), "wikipedia"))
}

Die Gartenlaube: Nearby

#------------------------------------------------------------------------------------
#title: Abfrage der Artikel der Gartenlaube rund 10km um Dresden
#------------------------------------------------------------------------------------
#defaultView:Map
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
SELECT ?item ?itemLabel ?subjectLabel ?coord ?layer
WHERE 
{
  ?item wdt:P1433 wd:Q655617. # alle Artikel in der Gartenlaube
  ?item wdt:P921 ?subject.    # mit main subject
  ?subject wdt:P7046 ?hovcode.# dieses sollte in Sachsen liegen
  wd:Q1731 wdt:P625 ?Dresden. # grenze nochmals auf Radius um Dresden 10km ein
		  SERVICE wikibase:around {
		    ?subject wdt:P625 ?coord.
		    bd:serviceParam wikibase:center ?Dresden.
		    bd:serviceParam wikibase:radius "10".
		    bd:serviceParam wikibase:distance ?dist.
		  }
  
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Wer schrieb wie viel für Die Gartenlaube?

Scholia

Authors: https://scholia.toolforge.org/venue/Q655617#authors
Most cited authors: https://scholia.toolforge.org/venue/Q655617#most-cited-authors

Query-Service

Häufigkeitsverteilung: Anzahl Artikel je Autor und Jahr, Abfrage

Verteilung der Anzahl geschriebener Artikel in der Illustrierten "Die Gartenlaube" je Autor und Jahr Abfrage

Bocknetz

Bocknetz: Prof. s:Carl Ernst Bock referenziert w:Carl Ernst Bock, mittels Wikicite, Query: https://w.wiki/HdS

#------------------------------------------------------------------------------------
#title: Carl Ernst Bock war Prof. für Pathologische Anatomie @Uni_Leipzig... durch u.a. Die Gartenlaube, wurde er einem größeren Publikum bekannt. Bocknetz: Bock zitiert Bock.
#------------------------------------------------------------------------------------
#defaultView:Graph
SELECT ?Die_Gartenlaube ?Die_GartenlaubeLabel ?zitiert ?zitiertLabel ?edgeLabel ?rgb WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?Die_Gartenlaube wdt:P1433 wd:Q655617;
    wdt:P50 wd:Q75044.
  OPTIONAL { ?Die_Gartenlaube wdt:P2860 ?zitiert. }
  BIND("zitiert" AS ?edgeLabel)
  BIND("cbcbcb" AS ?rgb)
}

Siehe (i.w.S.) das c:Category:Bocknetz am w:Verbrechertisch der „Guten Quelle“ in Leipzig

Scholia & Die Datenlaube

Thema: https://scholia.toolforge.org/topic/Q61943025
Die Gartenlaube: Kritik, Zitate, Referenzen und Forschungsliteratur seit 1853 – mit Wikicite, Scholia und Die Datenlaube, https://scholia.toolforge.org/work/Q116956667, März 2023, doi: 10.5281/zenodo.7769405
Die Gartenlaube: https://scholia.toolforge.org/venue/Q655617
Johannes Proelß: Wie das erste Deutsche Parlament entstand, 1898, https://scholia.toolforge.org/work/Q97119574

Übersetzungen: Die Gartenlaube*multilingual

DieDatenlaube/Notizen#28._März, Query folgt

Die Datenlaube: Edits in 2023

#------------------------------------------------------------------------------------
#title: Die Gartenlaube-Items, die im Jahr 2023 bearbeitet wurden. 2022-Query siehe https://diedatenlaube.github.io/jahr_2022.html
#------------------------------------------------------------------------------------
SELECT ?artikel ?artikelLabel ?dateModified WHERE {

  ?artikel wdt:P1433 wd:Q655617; schema:dateModified ?dateModified.
  FILTER(YEAR(?dateModified)=2023)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?dateModified)

described by source: (Qid), in: Die Gartenlaube

#------------------------------------------------------------------------------------
#title: Items beschrieben von Artikeln (described by source #P1343), die in der Gartenlaube veröffentlicht wurden.
#------------------------------------------------------------------------------------
SELECT ?item ?itemLabel ?work ?workLabel
WHERE 
{
  ?item wdt:P1343 ?work.
  ?work wdt:P1433 wd:Q655617.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Illustrator:innen der Gartenlaube

#------------------------------------------------------------------------------------
#title: Illustrator:innen der Gartenlaube und die Zahl ihrer durch Die Datenlaube erschlossenen Werke
#------------------------------------------------------------------------------------
SELECT DISTINCT ?illustrator ?illustratorLabel ?PoBLabel (COUNT(*) as ?count)
WHERE 
{
  ?item wdt:P1433 wd:Q655617.
  ?item wdt:P110 ?illustrator.
  ?illustrator wdt:P19 ?PoB.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?illustrator ?illustratorLabel ?PoBLabel ORDER BY DESC( ?count ) LIMIT 49 # Zahl der angezeigten Illustrator:innen variierbar

Wikicite, Caviar für Die Gartenlaube

Wikicite, Caviar für Die Gartenlaube

#------------------------------------------------------------------------------------
# Query: https://w.wiki/3cyD, Wikicite-Korpus der ''Gartenlaube'' für das 19. Jahrhundert
#------------------------------------------------------------------------------------
SELECT ?item ?itemLabel ?citedWorkLabel ?kindofLabel (year(xsd:dateTime(?pubDate)) as ?pubYear)
WHERE 
{
  ?item wdt:P1433 wd:Q655617.   # Artikel in der Gartenlaube
  ?item wdt:P2860 ?citedWork.   # eine externe Quelle wird zitiert
  ?citedWork wdt:P31 ?kindof.   # Typ der externen Quelle
  ?citedWork wdt:P577 ?pubDate. # Publikationsdatum
  MINUS {
    ?citedWork wdt:P1433 wd:Q655617.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

vgl. DieDatenlaube/Wikicite

Dresden, in: Die Gartenlaube

#defaultView:ImageGrid
#------------------------------------------------------------------------------------
#title: Dresden in: Die Gartenlaube
#------------------------------------------------------------------------------------
SELECT DISTINCT ?image ?item (GROUP_CONCAT(?medialegend; SEPARATOR = " ") AS ?legende) WHERE { # Group-Concat wg. mehrzeiligen Bildunterschriften
  ?item wdt:P1433 wd:Q655617;  # Item in "Die Gartenlaube" veröffentlicht
    wdt:P921 wd:Q1731;         # Item hat Dresden als zentrales Thema
    p:P18 ?statement.          # nur Items mit Illustrationen
  ?statement ps:P18 ?image;
    pq:P2096 ?medialegend.     # Bildunterschriften extrahieren
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?image ?item

Wien, in: Die Datenlaube

#defaultView:ImageGrid
#------------------------------------------------------------------------------------
#title: Wien in: Die Gartenlaube
#------------------------------------------------------------------------------------
SELECT DISTINCT ?image ?item (GROUP_CONCAT(?medialegend; SEPARATOR = " ") AS ?legende) WHERE { # Group-Concat wg. mehrzeiligen Bildunterschriften
  ?item wdt:P1433 wd:Q655617;  # Item in "Die Gartenlaube" veröffentlicht
    wdt:P921 wd:Q1741;         # Item hat Wien als zentrales Thema
    p:P18 ?statement.          # nur Items mit Illustrationen
  ?statement ps:P18 ?image;
    pq:P2096 ?medialegend.     # Bildunterschriften extrahieren
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?image ?item

Scholia, Thema: Die Datenlaube

https://scholia.toolforge.org/topic/Q61943025

Galerie

Gartenlaube-Kalender für das Jahr 1898
Gartenlaube-Kalender für 1890, in: Die Gartenlaube, 1889, S. 708
Kinder-Gartenlaube
Wikisource-Broschüre, 2019
Wikidata-Broschüre, 2019
Graphic Recording der Digitalen Mittagspause von Bürger schaffen Wissen mit Jens Bemme zu Open Citizen Science
Wikipedia and Academic Libraries: A Global Project, 2021

Bibliothek

Die Datenlaube described by source: d:Q61943025#P1343
Handbuch Wikidata entstanden in einer Lehrveranstaltung von Ina Blümel im Studiengang Informationsmanagement an der Hochschule Hannover, SoSe 2021
Linked Open Storytelling (Q66631860) im Verlagsmarketing
Smolarski, Rene (2020): „Citizen Science in den Geschichtswissenschaften“. Jena. (= Das Frontend als ,Flaschenhals‘?: Mediävistische Ressourcen im World Wide Web und ihre Nutzungspotentiale für eine Digitale Prosopographie). Online unter: https://www.db-thueringen.de/receive/dbt_mods_00040826

Abgerufen von „https://de.wikiversity.org/w/index.php?title=Projekt:Datenlaube-Kalender_2023&oldid=932432“